Here are some calculations in Macaulay2 to compute the Chow ring of \(\mathrm{M}^+\) in Section 5.

First of all, we compute the total Chern class of \(\mathcal{U}\) in Proposition 5.1. We used Schubert2 package to compute Chern classes.

i1 : loadPackage "Schubert2";

i2 : R = QQ[b_1,b_2,d_2,Degrees=>{1,2,2}];

i3 : I = ideal(b_1^2*d_2-3*d_2^2,b_1^2*b_2-b_2*d_2-3*d_2^2,b_1^4+3*b_2^2-9*b_2*d_2-3*d_2^2,2*b_1*b_2*d_2-3*b_1*d_2^2,3*b_1*b_2^2-7*b_1*d_2^2);

o3 : Ideal of R

i4 : S = R/I;

i5 : b_3 = (-b_1^3+4*b_1*d_2)/3;

i6 : X = abstractVariety(6,S);

i7 : E = abstractSheaf(X,ChernClass=>1+b_1+b_2+b_3,Rank=>3);

i8 : F = abstractSheaf(X,ChernClass=>1+b_1+d_2,Rank=>2);

i9 : U = E^6-F^3;

i10 : print toString chern(U)
1+3*b_1+(3*b_1^2+6*b_2-3*d_2)+(-b_1^3+12*b_1*b_2+2*b_1*d_2)+(27*b_2^2-48*b_2*d_2+51*d_2^2)+28*b_1*d_2^2+56*d_2^3

Now we show Proposition 5.9. We show that the ideal \(J\) is equal to \(\ker i^*\) in the Chow ring \(\mathrm{A}^*(\mathrm{Q}) = S\), by computing the Hilbert polynomial of \(S/J\).

i1 : R = QQ[p,b_1,b_2,d_2,Degrees=>{1,1,2,2}];

i2 : I = ideal(b_1^2*d_2-3*d_2^2,b_1^2*b_2-b_2*d_2-3*d_2^2,b_1^4+3*b_2^2-9*b_2*d_2-3*d_2^2,2*b_1*b_2*d_2-3*b_1*d_2^2,3*b_1*b_2^2-7*b_1*d_2^2,p^12+3*p^11*b_1+3*p^10*(b_1^2+2*b_2-d_2)+p^9*(-b_1^3+12*b_1*b_2+2*b_1*d_2)+3*p^8*(9*b_2^2-16*b_2*d_2+17*d_2^2)+28*p^7*b_1*d_2^2+56*p^6*d_2^3);

o2 : Ideal of R

i3 : S = R/I;

i4 : J = ideal(b_2-d_2,b_1^2-3*d_2,d_2-b_1*p+3*p^2,b_1*b_2,d_2^2);

o4 : Ideal of S

i5 : apply(5, i -> hilbertFunction(i,S/J))

o5 = {1, 2, 2, 1, 0}

o5 : List

The Hilbert polynomial is equal to that of \(\mathrm{Fl}(V)\).

We check that the ring presentation in Proposition 5.9 has the expected Hilbert polynomial.

i1 : R = QQ[t,p,b_1,b_2,d_2,Degrees=>{1,1,1,2,2}];

i2 : I = ideal(b_1^2*d_2-3*d_2^2,b_1^2*b_2-b_2*d_2-3*d_2^2,b_1^4+3*b_2^2-9*b_2*d_2-3*d_2^2,2*b_1*b_2*d_2-3*b_1*d_2^2,3*b_1*b_2^2-7*b_1*d_2^2,p^12+3*p^11*b_1+3*p^10*(b_1^2+2*b_2-d_2)+p^9*(-b_1^3+12*b_1*b_2+2*b_1*d_2)+3*p^8*(9*b_2^2-16*b_2*d_2+17*d_2^2)+28*p^7*b_1*d_2^2+56*p^6*d_2^3,t*(b_2-d_2),t*(b_1^2-3*d_2),t*(d_2-b_1*p+3*p^2),t*b_1*b_2,t*d_2^2,t^14+(10*p+4/3*b_1)*t^13+(25*p*b_1-13*b_2)*t^12+40*p*b_2*t^11+(p+1/3*b_1)^10*(-3*b_1^2*b_2+5*b_1^2*d_2));

o2 : Ideal of R

i3 : apply(20, i -> hilbertFunction(i,R/I))

o3 = {1, 3, 8, 13, 17, 18, 19, 19, 19, 19, 19, 19, 18, 17, 13, 8, 3, 1, 0, 0}

o3 : List

Back