Chow ring of \(\mathrm{N}\)


Here are some calculations in Macaulay2 to compute the Chow ring of \(\mathrm{N}\) in Proposition 4.4.

Let \(R = \mathbb{Q}[\beta_1, \beta_2, \beta_3, \delta_1, \delta_2]\) be the polynomial ring. In the following code, be_i is \(\beta_i\), de_i is \(\delta_i\), and D is \(\Delta\). \(S\) is the quotient ring by the first relation \(b_1-d_1\). We generate six elements \(r_1, \cdots, r_6\) in \(I^a\), and compute \(s_i := r_i/\Delta\).

i1 : R = QQ[be_1,be_2,be_3,de_1,de_2,Degrees=>{1,2,3,1,2}];

i2 : I = ideal(be_1+be_2+be_3-de_1-de_2);

o2 : Ideal of R

i3 : S = R/I;

i4 : D = (be_1-be_2)*(be_2-be_3)*(be_3-be_1)*(de_1-de_2);

i5 : b_1 = be_1+be_2+be_3;

i6 : b_2 = be_1*be_2+be_2*be_3+be_3*be_1;

i7 : b_3 = be_1*be_2*be_3;

i8 : d_1 = de_1+de_2;

i9 : d_2 = de_1*de_2;

i10 : r1 = (be_1-be_2)*(be_1-de_1)^3*(be_2-de_1)^3+(be_2-be_3)*(be_2-de_1)^3*(be_3-de_1)^3+(be_3-be_1)*(be_3-de_1)^3*(be_1-de_1)^3-(be_1-be_2)*(be_1-de_2)^3*(be_2-de_2)^3-(be_2-be_3)*(be_2-de_2)^3*(be_3-de_2)^3-(be_3-be_1)*(be_3-de_2)^3*(be_1-de_2)^3;

i11 : s1 = -b_1^3+4*b_1*d_2-3*b_3;

i12 : r2 = de_1*(be_1-be_2)*(be_1-de_1)^3*(be_2-de_1)^3+de_1*(be_2-be_3)*(be_2-de_1)^3*(be_3-de_1)^3+de_1*(be_3-be_1)*(be_3-de_1)^3*(be_1-de_1)^3-de_2*(be_1-be_2)*(be_1-de_2)^3*(be_2-de_2)^3-de_2*(be_2-be_3)*(be_2-de_2)^3*(be_3-de_2)^3-de_2*(be_3-be_1)*(be_3-de_2)^3*(be_1-de_2)^3;

i13 : s2 = -b_1^4+5*b_1^2*d_2-2*b_1*b_3-b_2^2+3*b_2*d_2-6*d_2^2;

i14 : r3 = (be_1^2-be_2^2)*(be_1-de_1)^3*(be_2-de_1)^3+(be_2^2-be_3^2)*(be_2-de_1)^3*(be_3-de_1)^3+(be_3^2-be_1^2)*(be_3-de_1)^3*(be_1-de_1)^3-(be_1^2-be_2^2)*(be_1-de_2)^3*(be_2-de_2)^3-(be_2^2-be_3^2)*(be_2-de_2)^3*(be_3-de_2)^3-(be_3^2-be_1^2)*(be_3-de_2)^3*(be_1-de_2)^3;

i15 : s3 = -b_1^2*b_2+b_2*d_2+3*d_2^2;

i16 : r4 = de_1*(be_1^2-be_2^2)*(be_1-de_1)^3*(be_2-de_1)^3+de_1*(be_2^2-be_3^2)*(be_2-de_1)^3*(be_3-de_1)^3+de_1*(be_3^2-be_1^2)*(be_3-de_1)^3*(be_1-de_1)^3-de_2*(be_1^2-be_2^2)*(be_1-de_2)^3*(be_2-de_2)^3-de_2*(be_2^2-be_3^2)*(be_2-de_2)^3*(be_3-de_2)^3-de_2*(be_3^2-be_1^2)*(be_3-de_2)^3*(be_1-de_2)^3;

i17 : s4 = -b_1^3*b_2+b_1^2*b_3+5*b_1*b_2*d_2-b_1*b_2^2+b_2*b_3-6*b_3*d_2;

i18 : r5 = (be_1-be_2)*(be_3-de_1)^3*(be_3-de_2)^3*(de_1-de_2)+(be_2-be_3)*(be_1-de_1)^3*(be_1-de_2)^3*(de_1-de_2)+(be_3-be_1)*(be_2-de_1)^3*(be_2-de_2)^3*(de_1-de_2);

i19 : s5 = b_1*b_3-b_2^2+3*b_2*d_2-3*d_2^2;

i20 : r6 = (be_1-be_2)*(be_2-be_3)*(be_3-be_1)*((be_1-de_1)^3*(be_2-de_1)^3+(be_2-de_1)^3*(be_3-de_1)^3+(be_3-de_1)^3*(be_1-de_1)^3-(be_1-de_2)^3*(be_2-de_2)^3-(be_2-de_2)^3*(be_3-de_2)^3-(be_3-de_2)^3*(be_1-de_2)^3);

i21 : s6 = b_1^5-3*b_1^3*b_2-4*b_1^3*d_2+6*b_1^2*b_3+9*b_1*b_2*d_2+3*b_1*d_2^2+3*b_2*b_3-21*b_3*d_2;

We check that \(s_i = r_i/\Delta\).

i22 : r1//D == s1

o22 = true

i23 : r2//D == s2

o23 = true

i24 : r3//D == s3

o24 = true

i25 : r4//D == s4

o25 = true

i26 : r5//D == s5

o26 = true

i27 : r6//D == s6

o27 = true

Then we obtain a ring presentation with four generators \(b_1, b_2, b_3, d_2\). We eliminate \(b_3\) and find a new presentation.

i1 : T = QQ[b_3,b_1,b_2,d_2,Degrees=>{3,1,2,2},MonomialOrder=>Eliminate 1];

i2 : J = ideal(-b_1^3+4*b_1*d_2-3*b_3,-b_1^4+5*b_1^2*d_2-2*b_1*b_3-b_2^2+3*b_2*d_2-6*d_2^2,-b_1^2*b_2+b_2*d_2+3*d_2^2,-b_1^3*b_2+b_1^2*b_3+5*b_1*b_2*d_2-b_1*b_2^2+b_2*b_3-6*b_3*d_2,b_1*b_3-b_2^2+3*b_2*d_2-3*d_2^2,b_1^5-3*b_1^3*b_2-4*b_1^3*d_2+6*b_1^2*b_3+9*b_1*b_2*d_2+3*b_1*d_2^2+3*b_2*b_3-21*b_3*d_2);

o2 : Ideal of T

i3 : print toString ideal selectInSubring(1,gens gb J)
ideal(b_1^2*d_2-3*d_2^2,b_1^2*b_2-b_2*d_2-3*d_2^2,b_1^4+3*b_2^2-9*b_2*d_2-3*d_2^2,2*b_1*b_2*d_2-3*b_1*d_2^2,3*b_1*b_2^2-7*b_1*d_2^2,2*b_2*d_2^2-3*d_2^3,2*b_2^2*d_2-5*d_2^3,2*b_2^3-9*d_2^3,b_1*d_2^3,d_2^4)

The obtained relation ideal has several redundant relations. We remove them and check that the new relation ideal is same to the above one.

i1 : T = QQ[b_1,b_2,d_2,Degrees=>{1,2,2}];

i2 : I = ideal(b_1^2*d_2-3*d_2^2,b_1^2*b_2-b_2*d_2-3*d_2^2,b_1^4+3*b_2^2-9*b_2*d_2-3*d_2^2,2*b_1*b_2*d_2-3*b_1*d_2^2,3*b_1*b_2^2-7*b_1*d_2^2,2*b_2*d_2^2-3*d_2^3,2*b_2^2*d_2-5*d_2^3,2*b_2^3-9*d_2^3,b_1*d_2^3,d_2^4);

o2 : Ideal of T

i3 : J = ideal(b_1^2*d_2-3*d_2^2,b_1^2*b_2-b_2*d_2-3*d_2^2,b_1^4+3*b_2^2-9*b_2*d_2-3*d_2^2,2*b_1*b_2*d_2-3*b_1*d_2^2,3*b_1*b_2^2-7*b_1*d_2^2);

o3 : Ideal of T

i4 : I == J

o4 = true

Finally, we check that the presentation \(T/J\) has the expected Hilbert series.

i5 : apply(10, i -> hilbertFunction(i,T/J))

o5 = {1, 1, 3, 3, 3, 1, 1, 0, 0, 0}

o5 : List

Back